PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

pkgname=pcmanfm-git
pkgver=1.2.1.r3.g8a2c79c
pkgrel=1

pkgdesc="An extremely fast, lightweight, yet feature-rich file manager with tabbed browsing"
url="http://pcmanfm.sourceforge.net/"
arch=('i686' 'x86_64')
license=('GPL')

depends=('libfm-gtk-git')
makedepends=('git' 'intltool' 'pkg-config')
optdepends=('gvfs: mounting of local and remote drives'
            'lxmenu-data: applications menu and "Open with" dialog'
            'gnome-menus: applications menu and "Open with" dialog')

provides=('pcmanfm')
conflicts=('pcmanfm')

install=pcmanfm.install
source=('git://git.lxde.org/git/lxde/pcmanfm'
        pcmanfm.install)

md5sums=('SKIP'
         'fc9ea2af71f55f32c8b22bf5ea879e69')

pkgver() {
	cd pcmanfm
	git describe --always --long | sed 's/-/-r/; s/-/./g'
}

build() {
	cd pcmanfm
	./autogen.sh
	./configure --prefix=/usr --sysconfdir=/etc
	make LDFLAGS="-lm ${LDFLAGS}"
}

package() {
	make -C pcmanfm DESTDIR="$pkgdir" install
}