blob: 96e1f083dd4b9594d2fb233d478e97f30e1039d8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor: Dmitry Korzhevin <dkorzhevin AT gmail DOT com>
# Contributor: Mark Foxwell <fastfret79@archlinux.org.uk>
# Contributor: Licia Todd <tigrmesh at aol dot com>
# Contributor: Tim Zebulla <amon at faumrahrer dot de>
# Contributor: Johannes Löthberg <johannes@kyriasis.com>
pkgname=weechat-git
pkgver=0.4.2.r24.g3088d31
pkgrel=1
pkgdesc="Fast, light & extensible IRC client (curses UI)"
arch=('i686' 'x86_64')
url="http://www.weechat.org/"
license=('GPL3')
depends=('gnutls' 'ncurses' 'libgcrypt')
makedepends=('git' 'cmake' 'pkgconfig' 'perl' 'python2' 'lua' 'tcl' 'ruby' 'aspell')
optdepends=('perl' 'python2' 'lua' 'tcl' 'ruby' 'aspell')
provides=('weechat')
conflicts=('weechat')
options=(!libtool)
source=("$pkgname::git://git.savannah.nongnu.org/weechat.git")
md5sums=('SKIP')
pkgver(){
cd $pkgname
printf "%s" "$(git describe --tags --long | sed 's/^v//; s/-/-r/' | tr - .)"
}
build() {
cd $pkgname
cmake -DPREFIX=/usr \
-DPYTHON_EXECUTABLE=/usr/bin/python2 \
-DPYTHON_LIBRARY=/usr/lib/libpython2.7.so\
-DENABLE_MAN=ON \
-DENABLE_DOC=OFF \
-DWEECHAT_HOME=~/.config/weechat
make
}
package() {
make -C $pkgname DESTDIR="$pkgdir" install
}
# vim: set ts=4 sw=4 noet:
|