blob: 5a7e804f21196b3cc993e2c96939696a102a746b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Johannes Löthberg <johannes@kyriasis.com>
# Contributor: TDY <tdy@gmx.com>
pkgname=pcmanfm-git
pkgver=1.1.2.r36.g9b9dd4c
pkgrel=2
pkgdesc="An extremely fast, lightweight, yet feature-rich file manager with tabbed browsing"
arch=('i686' 'x86_64')
url="http://pcmanfm.sourceforge.net/"
license=('GPL')
depends=('libfm-gtk-git')
makedepends=('git' 'intltool' 'pkg-config')
optdepends=('gvfs: mounting of local and remote drives'
'gnome-menus: applications menu and "Open with..." dialog')
provides=('pcmanfm')
conflicts=('pcmanfm')
install=pcmanfm.install
source=('git+https://pcmanfm.git.sourceforge.net/gitroot/pcmanfm/pcmanfm')
md5sums=('SKIP')
pkgver() {
cd pcmanfm
printf "%s" "$(git describe --always --long | sed 's/-/-r/' | tr - .)"
}
build() {
cd pcmanfm
./autogen.sh
./configure --prefix=/usr --sysconfdir=/etc
make LDFLAGS="-lm ${LDFLAGS}"
}
package() {
make -C pcmanfm DESTDIR="$pkgdir" install
}
# vim: set ts=4 sw=4 noet:
|