PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

pkgname=bemenu-git
pkgver=r216.064e937
pkgrel=1

pkgdesc='Dynamic menu library and client program inspired by dmenu'
url='https://github.com/Cloudef/bemenu'
license=('GPL3' 'LGPL3')
arch=('i686' 'x86_64')

depends=('pango')
makedepends=('git' 'cmake' 'libxkbcommon' 'libxinerama' 'wayland')
optdepends=('wayland: For the wayland backend.'
            'libxkbcommon: For the wayland backend.'
            'libxinerama: For the x11 backend.'
            'ncurses: For the curses backend.')

provides=('bemenu')
conflicts=('bemenu')

source=('git+https://github.com/Cloudef/bemenu')

md5sums=('SKIP')

pkgver() {
    cd bemenu
    printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git describe --always)"
}

build() {
    cd bemenu
    cmake -DCMAKE_INSTALL_PREFIX=/usr
    make
}

check() {
    cd bemenu
    make test
}

package() {
    cd bemenu
    make DESTDIR="$pkgdir" install
}