blob: 8989b6abede2580fb9cf7bf03bf8a1244357632c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Adrian Sampson <adrian@radbox.org>
# Contributor: Johannes Löthberg <johannes@kyriasis.com>
pkgname=beets-git
pkgver=1.3.1.r149.ge8d6c94
pkgrel=1
pkgdesc="Flexible music library manager and tagger - git version"
arch=('any')
url="http://beets.radbox.org/"
license=('MIT')
depends=('python2-munkres' 'mutagen'
'python2-setuptools' 'python2-unidecode'
'python2-musicbrainzngs' 'python2-yaml')
makedepends=('git')
optdepends=('python2-pyacoustid: acoustic fingerprinting'
'python2-flask: web interface'
'gstreamer0.10-python: BPD audio player plugin'
'python2-pylast: lastgenre plugin')
provides=('beets')
conflicts=('beets')
source=('git+https://github.com/sampsyo/beets.git')
md5sums=('SKIP')
pkgver() {
cd beets
git describe --tags --long | sed 's/^v//; s/-/-r/; s/-/./g'
}
build() {
cd beets
python2 setup.py build
}
package() {
cd beets
python2 setup.py install --root="$pkgdir" --optimize=1
install -D -m644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim: set ts=4 sw=4 noet:
|