From 1b08a10ec48351547383f37dfe9167839947657d Mon Sep 17 00:00:00 2001
From: Johannes Löthberg <johannes@kyriasis.com>
Date: Sun, 20 Oct 2013 21:31:35 +0200
Subject: weechat-git: Added weechat-git with personal modifications

Modifications:
* Use ~/.config/weechat instead of ~/.weechat
* Use better version numbering
---
 PKGBUILD | 44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 PKGBUILD

(limited to 'PKGBUILD')

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..96e1f08
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Daniel Wallace <danielwallace at gtmanfred dot com>
+# Contributor: Dmitry Korzhevin <dkorzhevin AT gmail DOT com>
+# Contributor: Mark Foxwell <fastfret79@archlinux.org.uk>
+# Contributor: Licia Todd <tigrmesh at aol dot com>
+# Contributor: Tim Zebulla <amon at faumrahrer dot de>
+# Contributor: Johannes Löthberg <johannes@kyriasis.com>
+
+pkgname=weechat-git
+pkgver=0.4.2.r24.g3088d31
+pkgrel=1
+pkgdesc="Fast, light & extensible IRC client (curses UI)"
+arch=('i686' 'x86_64')
+url="http://www.weechat.org/"
+license=('GPL3')
+depends=('gnutls' 'ncurses' 'libgcrypt')
+makedepends=('git' 'cmake' 'pkgconfig' 'perl' 'python2' 'lua' 'tcl' 'ruby' 'aspell')
+optdepends=('perl' 'python2' 'lua' 'tcl' 'ruby' 'aspell')
+provides=('weechat')
+conflicts=('weechat')
+options=(!libtool)
+source=("$pkgname::git://git.savannah.nongnu.org/weechat.git")
+md5sums=('SKIP')
+
+pkgver(){
+	cd $pkgname
+	printf "%s" "$(git describe --tags --long | sed 's/^v//; s/-/-r/' | tr - .)" 
+}
+
+build() {
+	cd $pkgname
+	cmake -DPREFIX=/usr \
+		  -DPYTHON_EXECUTABLE=/usr/bin/python2 \
+		  -DPYTHON_LIBRARY=/usr/lib/libpython2.7.so\
+		  -DENABLE_MAN=ON \
+		  -DENABLE_DOC=OFF \
+		  -DWEECHAT_HOME=~/.config/weechat
+	make
+}
+
+package() {
+	make -C $pkgname DESTDIR="$pkgdir" install
+}
+
+# vim: set ts=4 sw=4 noet:
-- 
cgit v1.2.3-70-g09d2